Labels -- custom labels for irreducible characters

Description

This optional input is used with the method characterTable provided by the package BettiCharacters.

By default, irreducible characters in a character table are labeled as $\chi_0, \chi_1, \dots$, etc. The user may pass custom labels in a list using this option. Labels can be passed as a list containing two lists: the first list should contain strings or nets to label characters in a M2 interactive session, while the second list should contain TeX strings to label characters when outputting to TeX format (remember to escape backslashes as needed). Up to version 2.1, a single list of net labels was accepted; this option is maintained for compatibility (the same labels are also used for the TeX output).

The next example sets up the character table of the dihedral group $D_4$, generated by an order 4 rotation $r$ and an order 2 reflection $s$ with the relation $srs=r^3$. The representatives of the conjugacy classes are, in order: the identity, $r^2$, $r$, $s$, and $rs$. Besides the trivial representation, $D_4$ has three irreducible one-dimensional representations, corresponding to the three normal subgroups of index two: $\langle r\rangle$, $\langle r^,,s\rangle$, and $\langle r^2,rs\rangle$. The characters of these representations send the elements of the corresponding subgroup to 1, and the other elements to -1. We denote those characters rho1,rho2,rho3. Finally, there is a unique irreducible representation of dimension 2.

i1 : R = QQ[x,y]

o1 = R

o1 : PolynomialRing

i2 : D8 = { matrix{{x,y}},
            matrix{{-x,-y}},
            matrix{{-y,x}},
            matrix{{x,-y}},
            matrix{{y,x}} }

o2 = {| x y |, | -x -y |, | -y x |, | x -y |, | y x |}

o2 : List

i3 : M = matrix {{1,1,1,1,1},
         {1,1,1,-1,-1},
         {1,1,-1,1,-1},
         {1,1,-1,-1,1},
         {2,-2,0,0,0}};

              5       5
o3 : Matrix ZZ  <-- ZZ

i4 : T = characterTable({1,1,2,2,2},M,QQ,{1,2,3,4,5},
         Labels=>{{"triv","rho1","rho2","rho3","dim2"},
             {"triv","\\rho_1","\\rho_2","\\rho_3","\\chi^2"}})

o4 = Character table over QQ
      
           |  1   1   2   2   2
     ------+-------------------
     triv  |  1   1   1   1   1
     rho1  |  1   1   1  -1  -1
     rho2  |  1   1  -1   1  -1
     rho3  |  1   1  -1  -1   1
     dim2  |  2  -2   0   0   0

o4 : CharacterTable

i5 : tex T

o5 = $\begin{array}{c|rrrrr}
     &1&1&2&2&2\\ \hline
     triv&1&1&1&1&1\\ 
     \rho_1&1&1&1&-1&-1\\ 
     \rho_2&1&1&-1&1&-1\\ 
     \rho_3&1&1&-1&-1&1\\ 
     \chi^2&2&-2&0&0&0
     \end{array}$

The same labels are automatically used when decomposing characters against a labeled character table.

i6 : A = action(R,D8)

o6 = PolynomialRing with 5 actors

o6 : ActionOnGradedModule

i7 : c = character(A,0,5)

o7 = Character over QQ
      
     (0, {0})  |  1   1   1  1  1
     (0, {1})  |  2  -2   0  0  0
     (0, {2})  |  3   3  -1  1  1
     (0, {3})  |  4  -4   0  0  0
     (0, {4})  |  5   5   1  1  1
     (0, {5})  |  6  -6   0  0  0

o7 : Character

i8 : d = decomposeCharacter(c,T)

o8 = Decomposition table
      
               |  triv  rho1  rho2  rho3  dim2
     ----------+------------------------------
     (0, {0})  |     1     0     0     0     0
     (0, {1})  |     0     0     0     0     1
     (0, {2})  |     1     0     1     1     0
     (0, {3})  |     0     0     0     0     2
     (0, {4})  |     2     1     1     1     0
     (0, {5})  |     0     0     0     0     3

o8 : CharacterDecomposition

i9 : tex d

o9 = $\begin{array}{c|rrrrr}
     &triv&\rho_1&\rho_2&\rho_3&\chi^2\\ \hline
     \left(0,\,\left\{0\right\}\right)&1&0&0&0&0\\ 
     \left(0,\,\left\{1\right\}\right)&0&0&0&0&1\\ 
     \left(0,\,\left\{2\right\}\right)&1&0&1&1&0\\ 
     \left(0,\,\left\{3\right\}\right)&0&0&0&0&2\\ 
     \left(0,\,\left\{4\right\}\right)&2&1&1&1&0\\ 
     \left(0,\,\left\{5\right\}\right)&0&0&0&0&3
     \end{array}$

The labels are stored in the character table under the key Labels. In particular, two character tables of the same group that are equal in all aspects except for their labels will fail an equality check.

Functions with optional argument named Labels:

characterTable(...,Labels=>...)

For the programmer

The object Labels is a symbol.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/BettiCharacters.m2:3859:0.

Labels -- custom labels for irreducible characters

Description

See also

Functions with optional argument named Labels:

For the programmer