character(PolynomialRing,HashTable) -- construct a character

Function: character
Usage:

character(R,H)
Inputs:
- R, a polynomial ring, a polynomial ring over a field
- H, a hash table, raw character data
Optional inputs:
- Semidirect => ..., default value (FunctionClosure[../BettiCharacters.m2:89:14-89:22],identity), action of semidirect product with torus
Outputs:
- an instance of the type Character,

Description

The character method is mainly designed to compute characters of finite group actions defined via action. The user who wishes to define characters by hand may do so with this particular application of the method.

The first argument is a polynomial ring over a field. The character inherits the grading of this polynomial ring and takes values in the field of coefficients. The second argument is a hash table containing the "raw" character data. The hash table entries are in the format (i,d) => c, where i is an integer representing homological degree, d is a list representing the internal (multi)degree, and c is a one-row matrix containing the values of the character in the given degrees.

i1 : R = QQ[x_1..x_3]

o1 = R

o1 : PolynomialRing

i2 : regularRepresentation = character(R, hashTable {
             (0,{0}) => matrix{{1,1,1}},
             (0,{1}) => matrix{{-1,0,2}},
             (0,{2}) => matrix{{-1,0,2}},
             (0,{3}) => matrix{{1,-1,1}},
             })

o2 = Character over QQ
      
     (0, {0})  |   1   1  1
     (0, {1})  |  -1   0  2
     (0, {2})  |  -1   0  2
     (0, {3})  |   1  -1  1

o2 : Character

i3 : I = ideal(x_1+x_2+x_3,x_1*x_2+x_1*x_3+x_2*x_3,x_1*x_2*x_3)

o3 = ideal (x  + x  + x , x x  + x x  + x x , x x x )
             1    2    3   1 2    1 3    2 3   1 2 3

o3 : Ideal of R

i4 : S3 = {matrix{{x_2,x_3,x_1}},
           matrix{{x_2,x_1,x_3}},
           matrix{{x_1,x_2,x_3}} }

o4 = {| x_2 x_3 x_1 |, | x_2 x_1 x_3 |, | x_1 x_2 x_3 |}

o4 : List

i5 : Q = R/I

o5 = Q

o5 : QuotientRing

i6 : A = action(Q,S3)

o6 = QuotientRing with 3 actors

o6 : ActionOnGradedModule

i7 : character(A,0,3) == regularRepresentation

o7 = true

Caveat

This constructor implements basic consistency checks, but it is still possible to construct objects that are not actually characters (not even virtual).

Ways to use this method:

character(PolynomialRing,HashTable) -- construct a character

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/BettiCharacters.m2:3859:0.

character(PolynomialRing,HashTable) -- construct a character

Description

Caveat

See also

Ways to use this method: