Macaulay2 » Documentation
Packages » CellularResolutions :: CellularResolutions
next | previous | forward | backward | up | index | toc

CellularResolutions -- A package for cellular resolutions of monomial ideals

Description

This package aims to make working with cellular resolutions of monomial ideals possible. Although the focus is on those constructs needed to work with cellular resolutions, the package additionally provides basic functions to work with cell complexes. For some direct ways to construct common cellular resolutions for monomial ideals, see taylorComplex and hullComplex. Introductions to cellular resolutions can be found in:

More generally, cell complexes can be constructed by creating cells using newCell or newSimplexCell, and then the maximal cells can be provided to cellComplex to construct a cell complex.

The example below follows Example 1.6 in Cellular resolutions of monomial modules, where two simplicial complexes X and Y are constructed on the same monomial ideal. However, only X supports a resolution.

i1 : S = QQ[a,b,c, Degrees=>{{1,0,0},{0,1,0},{0,0,1}}];
 
i2 : v101 = newCell({},a*c)

o2 = Cell of dimension 0 with label a*c

o2 : Cell
 
i3 : v012 = newCell({},b*c^2); v020 = newCell({},b^2); v210 = newCell({},a^2*b);
 
i6 : e112 = newCell({v101,v012})

                                         2
o6 = Cell of dimension 1 with label a*b*c

o6 : Cell
 
i7 : e022 = newCell({v012,v020}); e220 = newCell({v020,v210}); e211 = newCell({v210,v101});
 
i10 : e121 = newCell({v101,v020});
 
i11 : f122 = newCell({e112,e022,e121})

                                        2 2
o11 = Cell of dimension 2 with label a*b c

o11 : Cell
 
i12 : f221 = newCell({e220,e211,e121});
 
i13 : X = cellComplex(S,{f122,f221})

o13 = X

o13 : CellComplex
 
i14 : e212 = newCell({v210,v012}); f212 = newCell({e112,e211,e212}); f222 = newCell({e022,e220,e212});
 
i17 : Y = cellComplex(S,{f212,f222})

o17 = Y

o17 : CellComplex
 
i18 : prune HH X

o18 = cokernel | ac b2 bc2 a2b |
       
      -1

o18 : Complex
 
i19 : prune HH Y

o19 = cokernel | ac b2 bc2 a2b | <-- cokernel {1, 2, 1} | c a |
                                      
      -1                             0

o19 : Complex
 
i20 : Y121 = subcomplex(Y,a*b^2*c)

o20 = Y121

o20 : CellComplex
 
i21 : prune HH Y121

        1
o21 = QQ
       
      0

o21 : Complex

Authors

Version

This documentation describes version 1.1 of CellularResolutions, released December 23, 2025.

Citation

If you have used this package in your research, please cite it as follows:

@misc{CellularResolutionsSource,
  title = {{CellularResolutions: cellular resolutions of monomial ideals. Version~1.1}},
  author = {Jay Yang and Aleksandra Sobieska},
  howpublished = {A \emph{Macaulay2} package available at
    \url{https://github.com/Macaulay2/M2/tree/stable/M2/Macaulay2/packages}}
}

Exports

  • Types
    • Cell -- the class of all cells in cell complexes
    • CellComplex -- the class of all cell complexes
  • Functions and commands
  • Methods
    • boundary(Cell) -- see boundary -- returns the boundary cells along with relative orientations
    • boundaryCells(Cell) -- see boundaryCells -- returns the boundary cells of the given cell
    • boundaryMap(ZZ,CellComplex) -- compute the boundary map of a cell complex from r-faces to (r-1)-faces
    • cellComplex(Ring,List) -- see cellComplex -- create a cell complex
    • cellComplex(Ring,PolyhedralComplex) -- creates cell complex from given polyhedral complex
    • cellComplex(Ring,Polyhedron) -- creates cell complex from given polyhedron
    • cellComplex(Ring,SimplicialComplex) -- Creates a cell complex from a given simplicial complex
    • cellComplexRPn(Ring,ZZ) -- see cellComplexRPn -- gives a $RP^n$ as a cell complex
    • cellComplexSphere(Ring,ZZ) -- see cellComplexSphere -- gives a sphere as a cell complex
    • cellComplexTorus(Ring,ZZ) -- see cellComplexTorus -- gives a torus as a cell complex
    • cellLabel(Cell) -- see cellLabel -- return the label of a cell
    • cells(CellComplex) -- see cells -- return the cells of a cell complex as a hashtable whose keys are cell dimensions
    • cells(ZZ,CellComplex) -- return the cells of a cell complex
    • complex(CellComplex) -- compute the cellular chain complex for a cell complex
    • describe(CellComplex) -- Describes a cell complex or cell
    • dim(Cell) -- compute the dimension of a cell
    • dim(CellComplex) -- compute the dimension of a cell complex
    • facePoset(CellComplex) -- generates the face poset of a cell complex
    • HH CellComplex -- compute the homology modules of a cell complex
    • HH^ZZ CellComplex -- cohomology of a cell complex
    • HH_ZZ CellComplex -- compute the homology modules of a cell complex
    • hullComplex(MonomialIdeal) -- see hullComplex -- gives the hull complex of a monomial ideal
    • hullComplex(QQ,MonomialIdeal) -- see hullComplex -- gives the hull complex of a monomial ideal
    • hullComplex(ZZ,MonomialIdeal) -- see hullComplex -- gives the hull complex of a monomial ideal
    • isCycle(List) -- see isCycle -- checks if a list of cells with orientation make a cycle
    • isFree(CellComplex) -- checks if the labels of a cell complex are free modules
    • isMinimal(CellComplex) -- see isMinimal -- check if a labeled cell complex supports a minimal resolution
    • isSimplex(Cell) -- see isSimplex -- check if a cell is a simplex
    • isWellDefined(Cell) -- checks if a cell is well defined
    • isWellDefined(CellComplex) -- checks if a cell complex is well defined
    • maxCells(CellComplex) -- see maxCells -- gives the maximal cells of a cell complex
    • net(Cell) -- see net(CellComplex) -- Describes a cell complex or cell
    • net(CellComplex) -- Describes a cell complex or cell
    • newCell(List) -- see newCell -- creates a new cell
    • newCell(List,Ideal) -- see newCell -- creates a new cell
    • newCell(List,Module) -- see newCell -- creates a new cell
    • newCell(List,Number) -- see newCell -- creates a new cell
    • newCell(List,RingElement) -- see newCell -- creates a new cell
    • newSimplexCell(List) -- see newSimplexCell -- create a new cell
    • newSimplexCell(List,Ideal) -- see newSimplexCell -- create a new cell
    • newSimplexCell(List,Module) -- see newSimplexCell -- create a new cell
    • newSimplexCell(List,Number) -- see newSimplexCell -- create a new cell
    • newSimplexCell(List,RingElement) -- see newSimplexCell -- create a new cell
    • relabelCellComplex(CellComplex,HashTable) -- see relabelCellComplex -- relabels a cell complex
    • ring(CellComplex) -- return the base ring of a cell complex
    • RingMap ** CellComplex -- tensors labels via a ring map
    • scarfComplex(MonomialIdeal) -- see scarfComplex -- gives the hull complex of a monomial ideal
    • skeleton(ZZ,CellComplex) -- computes the $r$-skeleton of a cell complex
    • CellComplex _ List -- see subcomplex -- the subcomplex induced by a degree or monomial
    • CellComplex _ RingElement -- see subcomplex -- the subcomplex induced by a degree or monomial
    • CellComplex _ ZZ -- see subcomplex -- the subcomplex induced by a degree or monomial
    • subcomplex(CellComplex,List) -- see subcomplex -- the subcomplex induced by a degree or monomial
    • subcomplex(CellComplex,RingElement) -- see subcomplex -- the subcomplex induced by a degree or monomial
    • subcomplex(CellComplex,ZZ) -- see subcomplex -- the subcomplex induced by a degree or monomial
    • taylorComplex(MonomialIdeal) -- see taylorComplex -- gives the Taylor complex of a monomial ideal
    • texMath(Cell) -- see texMath(CellComplex) -- Describes a cell complex or cell using TeX
    • texMath(CellComplex) -- Describes a cell complex or cell using TeX
  • Symbols
    • Reduced -- see complex(CellComplex) -- compute the cellular chain complex for a cell complex
    • CellDimension -- see newCell -- creates a new cell
    • InferLabels -- see relabelCellComplex -- relabels a cell complex
    • LabelRing -- see subcomplex -- the subcomplex induced by a degree or monomial

For the programmer

The object CellularResolutions is a package, defined in CellularResolutions.m2, with auxiliary files in CellularResolutions/.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/CellularResolutions/doc.m2:82:0.