DGIdeal ** Ring -- Base change of a DG ideal along a ring map

Operator: **
Usage:

IS = I ** S
Inputs:
- I, an instance of the type DGIdeal, A DG ideal of some DG algebra A.
- S, a ring,
Outputs:
- IS, an instance of the type DGIdeal, The DG ideal of A ** S generated by the images of the original generators of I under substitute.

Description

Unlike ** Ideal (which is not defined — see the note in Base change and tensor with non-DG types), this operation does land inside the DG world: DGIdeal is always generated by elements, so substitution along the ring map of base change produces a well-formed DGIdeal of A ** S.

i1 : R = ZZ/101[x,y]

o1 = R

o1 : PolynomialRing

i2 : A = koszulComplexDGA R

o2 = {Ring => R                          }
      Underlying algebra => R[T   ..T   ]
                               1,1   1,2
      Differential => {x, y}

o2 : DGAlgebra

i3 : Anat = A.natural

o3 = Anat

o3 : PolynomialRing, 2 skew commutative variable(s)

i4 : I = dgIdeal(A, {x_Anat, y_Anat})

o4 = DGIdeal of Anat
     generators => | y x |

o4 : DGIdeal

i5 : QR = R / ideal(x^2)

o5 = QR

o5 : QuotientRing

i6 : IQ = I ** QR

o6 = DGIdeal of QR[T   ..T   ]
                    1,1   1,2
     generators => | y x |

o6 : DGIdeal

i7 : isWellDefined IQ

o7 = true

i8 : IQ.dgAlgebra === A ** QR

o8 = true

Base change preserves the zero and unit DG ideals: the zero ideal stays zero, and the unit ideal stays the whole algebra.

i9 : Z = dgIdeal(A, {})

o9 = DGIdeal of Anat
     generators => 0

o9 : DGIdeal

i10 : ZQ = Z ** QR

o10 = DGIdeal of QR[T   ..T   ]
                     1,1   1,2
      generators => 0

o10 : DGIdeal

i11 : isWellDefined ZQ and isZero ZQ

o11 = true

i12 : U = dgIdeal(A, {1_Anat})

o12 = DGIdeal of Anat
      generators => | 1 |

o12 : DGIdeal

i13 : UQ = U ** QR

o13 = DGIdeal of QR[T   ..T   ]
                     1,1   1,2
      generators => | 1 |

o13 : DGIdeal

i14 : isWellDefined UQ and not isZero UQ

o14 = true

Multivariate quotients and multi-generator DG ideals interact as expected.

i15 : R3 = ZZ/101[x,y,z]

o15 = R3

o15 : PolynomialRing

i16 : A3 = koszulComplexDGA R3

o16 = {Ring => R3                          }
       Underlying algebra => R3[T   ..T   ]
                                 1,1   1,3
       Differential => {x, y, z}

o16 : DGAlgebra

i17 : Anat3 = A3.natural

o17 = Anat3

o17 : PolynomialRing, 3 skew commutative variable(s)

i18 : I3 = dgIdeal(A3, {x_Anat3, y_Anat3, z_Anat3})

o18 = DGIdeal of Anat3
      generators => | z y x |

o18 : DGIdeal

i19 : QR3 = R3 / ideal(x*y, y*z)

o19 = QR3

o19 : QuotientRing

i20 : isWellDefined(I3 ** QR3)

o20 = true

Ways to use this method:

DGIdeal ** Ring -- Base change of a DG ideal along a ring map

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/DGAlgebras/doc.m2:1952:0.

DGIdeal ** Ring -- Base change of a DG ideal along a ring map

Description

See also

Ways to use this method: