baseChange -- Transport a DG algebra along a ring map on its base

Usage:

B = baseChange(A, S)

B = baseChange(A, phi)
Inputs:
- A, an instance of the type DGAlgebra, A DG algebra over some ring R.
- S, a ring, A target ring. Shorthand for baseChange(A, map(S, R)).
- phi, a ring map, A ring map with source R = underlyingRing A; its target becomes the base ring of B.
Optional inputs:
- InitializeDegreeZeroHomology => a Boolean value, default value true, Whether to compute H_0 of the result eagerly. Default true.
- InitializeComplex => a Boolean value, default value false, Whether to build the underlying complex of B eagerly. Default false.
Outputs:
- B, an instance of the type DGAlgebra, A DG algebra over target phi with the same generator hom-degrees as A, and whose differentials are the images of A.diff under the obvious extension of phi that sends each A-generator to the corresponding B-generator.

Description

Useful for lifting a Koszul DG algebra over a polynomial ring to one over a factor ring, or for specialization (via a ring map that kills some variables).

i1 : R = QQ[x, y]

o1 = R

o1 : PolynomialRing

i2 : A = koszulComplexDGA R

o2 = {Ring => R                          }
      Underlying algebra => R[T   ..T   ]
                               1,1   1,2
      Differential => {x, y}

o2 : DGAlgebra

i3 : S = R / ideal(x^2, y^2)

o3 = S

o3 : QuotientRing

i4 : B = baseChange(A, S)

o4 = {Ring => S                          }
      Underlying algebra => S[T   ..T   ]
                               1,1   1,2
      Differential => {x, y}

o4 : DGAlgebra

i5 : underlyingRing B === S

o5 = true

i6 : isWellDefinedDifferential B

o6 = true

An explicit ring map gives more flexibility:

i7 : R = QQ[x, y]

o7 = R

o7 : PolynomialRing

i8 : A = koszulComplexDGA R

o8 = {Ring => R                          }
      Underlying algebra => R[T   ..T   ]
                               1,1   1,2
      Differential => {x, y}

o8 : DGAlgebra

i9 : phi = map(R, R, {x, 0})

o9 = map (R, R, {x, 0})

o9 : RingMap R <-- R

i10 : Bphi = baseChange(A, phi)

o10 = {Ring => R                          }
       Underlying algebra => R[T   ..T   ]
                                1,1   1,2
       Differential => {x, 0}

o10 : DGAlgebra

i11 : underlyingRing Bphi === R

o11 = true

Caveat

Raises an error if source phi is not equal to underlyingRing A.

Ways to use baseChange:

baseChange(DGAlgebra,Ring)
baseChange(DGAlgebra,RingMap)

For the programmer

The object baseChange is a method function with options.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/DGAlgebras/doc.m2:6527:0.

baseChange -- Transport a DG algebra along a ring map on its base

Description

Caveat

See also

Ways to use baseChange:

For the programmer