dgQuotientModule -- Construct the quotient DG module M / S

Usage:

Q = dgQuotientModule(M, S)
Inputs:
- M, an instance of the type DGModule,
- S, an instance of the type DGSubmodule, With S.ambient === M.
Outputs:
- Q, an instance of the type DGQuotientModule, The cokernel of S.inclusion.natural equipped with the induced differential.

Description

The shorthand M / S calls this constructor. The resulting Q records the ambient M (via ambient), the killed submodule S (via subDGModule), and the quotient map M → Q (via projection).

i1 : R = ZZ/101[x]

o1 = R

o1 : PolynomialRing

i2 : A = koszulComplexDGA R

o2 = {Ring => R                    }
      Underlying algebra => R[T   ]
                               1,1
      Differential => {x}

o2 : DGAlgebra

i3 : M = freeDGModule(A, {0})

o3 = {Base ring => R               }
      DG algebra => R[T   ]
                       1,1
                                 1
      Natural module => (R[T   ])
                            1,1
      Generator degrees => {{0, 0}}
      Differentials on gens => {0}

o3 : DGModule

i4 : Z = dgSubmodule(M, {})

o4 = DGSubmodule of ambient DGModule
     Degrees  => {}
     natural  => 0
     inclusion => 0

o4 : DGSubmodule

i5 : Q = dgQuotientModule(M, Z)

o5 = DGQuotientModule Q = M / S
                          1
     Q.natural = (R[T   ])
                     1,1
     Degrees   = {{0, 0}}

o5 : DGQuotientModule

i6 : instance(Q, DGQuotientModule)

o6 = true

i7 : ambient Q === M

o7 = true

i8 : subDGModule Q === Z

o8 = true

Quotienting by the zero submodule gives a DGQuotientModule whose underlying cokernel is isomorphic to M.natural; quotienting by the whole ambient yields the zero DGQuotientModule.

i9 : Sfull = dgSubmodule(M, id_(M.natural))

o9 = DGSubmodule of ambient DGModule
     Degrees  => {{0, 0}}
                          1
     natural  => (R[T   ])
                     1,1
     inclusion => | 1 |

o9 : DGSubmodule

i10 : Qzero = M / Sfull

o10 = DGQuotientModule Q = M / S
      Q.natural = cokernel | 1 |
      Degrees   = {{0, 0}}

o10 : DGQuotientModule

i11 : isZero Qzero

o11 = true

Caveat

S.ambient must equal M as an object (===), not merely be isomorphic. This enforces a strict lattice-of-submodules discipline on the resulting quotient.

Ways to use dgQuotientModule:

dgQuotientModule(DGModule,DGSubmodule)

For the programmer

The object dgQuotientModule is a method function.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/DGAlgebras/doc.m2:3248:0.

dgQuotientModule -- Construct the quotient DG module M / S

Description

Caveat

See also

Ways to use dgQuotientModule:

For the programmer