diff(DGModule,Vector) -- Apply the DG module differential to an element

Function: diff
Usage:

dv = diff(M, v)
Inputs:
- M, an instance of the type DGModule, A DG module.
- v, a vector, A homogeneous element of M.natural.
Outputs:
- dv, a vector, The image d_M(v) in M.natural, computed via the Leibniz rule.

Description

Applies the Leibniz rule coordinate by coordinate. If v = sum_i f_i \cdot e_i where e_i are the free generators of M.natural and f_i \in A.natural, then d_M(v) = sum_i (d_A(f_i) \cdot e_i + (-1)^{|f_i|} f_i \cdot d_M(e_i)) where |f_i| is the hom-degree of f_i.

This element-level interface is the entry point for checking the cycle condition on a candidate homology class and for defining DGModuleMap objects without committing to the matrix-level bookkeeping of moduleDifferential.

i1 : R = QQ[x]

o1 = R

o1 : PolynomialRing

i2 : A = koszulComplexDGA R

o2 = {Ring => R                    }
      Underlying algebra => R[T   ]
                               1,1
      Differential => {x}

o2 : DGAlgebra

i3 : M = freeDGModule(A, {0, 1})

o3 = {Base ring => R                       }
      DG algebra => R[T   ]
                       1,1
                                 2
      Natural module => (R[T   ])
                            1,1
      Generator degrees => {{0, 0}, {1, 0}}
      Differentials on gens => {0, 0}

o3 : DGModule

i4 : natGens = apply(rank M.natural, i -> (M.natural)_i)

o4 = {| 1 |, | 0 |}
      | 0 |  | 1 |

o4 : List

i5 : setDiff(M, {0, x * natGens#0})

o5 = {Base ring => R                       }
      DG algebra => R[T   ]
                       1,1
                                 2
      Natural module => (R[T   ])
                            1,1
      Generator degrees => {{0, 0}, {1, 0}}
      Differentials on gens => {0, | x |}
                                   | 0 |

o5 : DGModule

i6 : diff(M, natGens#1)

o6 = | x |
     | 0 |

              2
o6 : (R[T   ])
         1,1

i7 : diff(M, natGens#0)

o7 = 0

              2
o7 : (R[T   ])
         1,1

Here d(e_1) = x \cdot e_0 and d(e_0) = 0.

Ways to use this method:

diff(DGModule,Vector) -- Apply the DG module differential to an element

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/DGAlgebras/doc.m2:6158:0.

diff(DGModule,Vector) -- Apply the DG module differential to an element

Description

See also

Ways to use this method: