image(DGModuleMap) -- Image of a DG module map as a DG submodule of its target

Function: image
Usage:

S = image f
Inputs:
- f, an instance of the type DGModuleMap, A morphism M -> N of DG modules over a common DG algebra.
Outputs:
- S, an instance of the type DGSubmodule, The DG submodule of N = target f whose column span in N.natural is the image of f.natural. Zero columns of f.natural are dropped, so the number of generators of the result reflects the rank of the image rather than the width of the presentation.

Description

Since f is a chain map, the column span of f.natural is already d-closed in N.natural; dgSubmodule is called without a d-saturation loop.

A substantive example: over R = k[x, y]/(x^2, y^2) take the Koszul DG module KM = koszulComplexDGM R^1 and the endomorphism "multiplication by x." Its image is a proper DG submodule -- it cannot be all of KM because x annihilates the class of 1 \in R modulo its own image (since x^2 = 0):

i1 : R = ZZ/101[x, y] / ideal(x^2, y^2)

o1 = R

o1 : QuotientRing

i2 : A = koszulComplexDGA R

o2 = {Ring => R                          }
      Underlying algebra => R[T   ..T   ]
                               1,1   1,2
      Differential => {x, y}

o2 : DGAlgebra

i3 : KM = koszulComplexDGM R^1

o3 = {Base ring => R                    }
      DG algebra => R[T   ..T   ]
                       1,1   1,2
                                       1
      Natural module => (R[T   ..T   ])
                            1,1   1,2
      Generator degrees => {{0, 0}}
      Differentials on gens => {0}

o3 : DGModule

i4 : mx = dgModuleMap(KM, KM, x * id_(KM.natural))

                               1
o4 = {Source => (R[T   ..T   ]) }
                    1,1   1,2
                               1
      Target => (R[T   ..T   ])
                    1,1   1,2
      Natural => | x |

o4 : DGModuleMap

i5 : imgMx = image mx

o5 = DGSubmodule of ambient DGModule
     Degrees  => {{0, 0}}
                                1
     natural  => (R[T   ..T   ])
                     1,1   1,2
     inclusion => | x |

o5 : DGSubmodule

i6 : isWellDefined imgMx

o6 = true

i7 : numcols (inclusion imgMx).natural

o7 = 1

i8 : isSubset(imgMx, dgSubmodule(KM, id_(KM.natural)))

o8 = true

The image of the inclusion of a DG submodule S \subset M recovers S itself:

i9 : Sfull = dgSubmodule(KM, id_(KM.natural));

i10 : (image (inclusion Sfull)) == Sfull

o10 = true

Ways to use this method:

image(DGModuleMap) -- Image of a DG module map as a DG submodule of its target

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/DGAlgebras/doc.m2:4015:0.

image(DGModuleMap) -- Image of a DG module map as a DG submodule of its target

Description

See also

Ways to use this method: