killHomologyAtDegree -- Adjoin variables killing the homology of a DG algebra at a prescribed degree

Usage:

B = killHomologyAtDegree(A, n)
Inputs:
- A, an instance of the type DGAlgebra,
- n, an integer, The hom-degree at which to kill homology.
Outputs:
- B, an instance of the type DGAlgebra, Either A itself (if H_n(A) = 0) or a new DG algebra obtained from A by adjoining variables in hom-degree n + 1 whose differentials are minimal representatives of H_n(A).

Description

Unlike killCycles, which searches for the first nontrivial degree upward from StartDegree, this method targets a specific degree. It computes the minimal generators of H_n(A) using the pruning map of prune homology(n, A), lifts them to cycles in A_n, and adjoins via adjoinVariables.

i1 : R = QQ[x, y]

o1 = R

o1 : PolynomialRing

i2 : A = koszulComplexDGA R

o2 = {Ring => R                          }
      Underlying algebra => R[T   ..T   ]
                               1,1   1,2
      Differential => {x, y}

o2 : DGAlgebra

i3 : killHomologyAtDegree(A, 1) === A

o3 = true

Over a regular ring, H_1 vanishes already, so the method short-circuits. Over a complete intersection, it adjoins new generators:

i4 : R = QQ[x, y] / ideal(x^2, y^2)

o4 = R

o4 : QuotientRing

i5 : A = koszulComplexDGA R

o5 = {Ring => R                          }
      Underlying algebra => R[T   ..T   ]
                               1,1   1,2
      Differential => {x, y}

o5 : DGAlgebra

i6 : B = killHomologyAtDegree(A, 1)

o6 = {Ring => R                             }
      Underlying algebra => R[T   ..T   ]
                               1,1   2,2
      Differential => {x, y, x*T   , y*T   }
                                1,1     1,2

o6 : DGAlgebra

i7 : numgens B.natural > numgens A.natural

o7 = true

i8 : prune homology(1, B)

o8 = 0

o8 : R-module

Ways to use killHomologyAtDegree:

killHomologyAtDegree(DGAlgebra,ZZ)

For the programmer

The object killHomologyAtDegree is a method function.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/DGAlgebras/doc.m2:6716:0.

killHomologyAtDegree -- Adjoin variables killing the homology of a DG algebra at a prescribed degree

Description

See also

Ways to use killHomologyAtDegree:

For the programmer