prune(DGQuotientModule) -- Minimize the presentation of a DG quotient module

Function: prune
Usage:

Qp = prune Q

Qp = minimalPresentation Q
Inputs:
- Q, an instance of the type DGQuotientModule,
Optional inputs:
- Exclude => ..., default value {},
Outputs:
- Qp, an instance of the type DGQuotientModule, A DG quotient module of the same ambient DG module whose relations submodule has been pruned, and whose toComplex Qp has additionally been pruned at the complex level.

Description

prune Q proceeds in two steps. First, it prunes the relations submodule Q.subDGModule using prune(DGSubmodule); this trims redundant columns from the inclusion matrix. If the inclusion was already minimal, Qp === Q.

Second, it computes prune (toComplex Qp) at the complex level and caches the result in Qp.cache under the symbol prunedComplex. After this, calling toComplex Qp returns a minimally presented complex and pruning commutes with toComplex: the complex-level prune of toComplex Qp is idempotent.

A pruningMap from Qp to Q is cached in Qp.cache as a DGModuleMap induced by the identity on M.natural.

i1 : R = ZZ/101[x, y]

o1 = R

o1 : PolynomialRing

i2 : A = koszulComplexDGA R

o2 = {Ring => R                          }
      Underlying algebra => R[T   ..T   ]
                               1,1   1,2
      Differential => {x, y}

o2 : DGAlgebra

i3 : Anat = A.natural

o3 = Anat

o3 : PolynomialRing, 2 skew commutative variable(s)

i4 : M = freeDGModule(A, {0})

o4 = {Base ring => R               }
      DG algebra => Anat
                            1
      Natural module => Anat
      Generator degrees => {{0, 0}}
      Differentials on gens => {0}

o4 : DGModule

i5 : S = dgSubmodule(M, matrix {{1_Anat, x_Anat, y_Anat}})

o5 = DGSubmodule of ambient DGModule
     Degrees  => {{0, 0}, {0, 1}, {0, 1}}
                     3
     natural  => Anat
     inclusion => | 1 x y |

o5 : DGSubmodule

i6 : Q = M / S

o6 = DGQuotientModule Q = M / S
     Q.natural = cokernel | 1 x y |
     Degrees   = {{0, 0}}

o6 : DGQuotientModule

i7 : Qp = prune Q

o7 = DGQuotientModule Q = M / S
     Q.natural = cokernel | 1 |
     Degrees   = {{0, 0}}

o7 : DGQuotientModule

i8 : image (inclusion Qp.subDGModule).natural == image (inclusion S).natural

o8 = true

If the cokernel is secretly zero, pruning collapses toComplex Qp to the zero complex, matching prune applied to Complex objects from the Complexes package on Complex.

minimalPresentation is a synonym for prune on DG quotient modules.

Ways to use this method:

prune(DGQuotientModule) -- Minimize the presentation of a DG quotient module

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/DGAlgebras/doc.m2:4682:0.

prune(DGQuotientModule) -- Minimize the presentation of a DG quotient module

Description

See also

Ways to use this method: