setDiff(DGModule,List) -- Install the list of generator differentials on a free DG module

Function: setDiff
Usage:

setDiff(M, diffList)
Inputs:
- M, an instance of the type DGModule, A free DG module (from freeDGModule).
- diffList, a list, One entry per natural generator of M. Each entry is a vector of M.natural (or 0, or a one-column matrix that will be folded into a vector).
Optional inputs:
- InitializeComplex => ..., default value true, Install or replace the differential on a DG algebra
- InitializeDegreeZeroHomology => ..., default value true, Install or replace the differential on a DG algebra
Outputs:
- an instance of the type DGModule, The same M, mutated to carry the new differentials.

Description

setDiff is the DG module analogue of setDiff(DGAlgebra,List): it records the image of the i-th natural generator under the differential in the i-th slot of M.diff, and clears every cached derived value so that later calls to moduleDifferential or homology will recompute from the newly installed data. Only free DG modules (those produced by freeDGModule) are accepted; the list length must match the number of natural generators.

i1 : R = QQ[x]

o1 = R

o1 : PolynomialRing

i2 : A = koszulComplexDGA R

o2 = {Ring => R                    }
      Underlying algebra => R[T   ]
                               1,1
      Differential => {x}

o2 : DGAlgebra

i3 : M = freeDGModule(A, {0, 1})

o3 = {Base ring => R                       }
      DG algebra => R[T   ]
                       1,1
                                 2
      Natural module => (R[T   ])
                            1,1
      Generator degrees => {{0, 0}, {1, 0}}
      Differentials on gens => {0, 0}

o3 : DGModule

i4 : natGens = apply(rank M.natural, i -> (M.natural)_i)

o4 = {| 1 |, | 0 |}
      | 0 |  | 1 |

o4 : List

i5 : setDiff(M, {0, x^2 * natGens#0})

o5 = {Base ring => R                       }
      DG algebra => R[T   ]
                       1,1
                                 2
      Natural module => (R[T   ])
                            1,1
      Generator degrees => {{0, 0}, {1, 0}}
      Differentials on gens => {0, | x2 |}
                                   |  0 |

o5 : DGModule

i6 : d1 = moduleDifferential(1, M)

o6 = | x x2 |

             1      2
o6 : Matrix R  <-- R

i7 : d2 = moduleDifferential(2, M)

o7 = {1} | -x2 |
     {0} | x   |

             2      1
o7 : Matrix R  <-- R

i8 : assert(d1 * d2 == 0)

Ways to use this method:

setDiff(DGModule,List) -- Install the list of generator differentials on a free DG module

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/DGAlgebras/doc.m2:7613:0.

setDiff(DGModule,List) -- Install the list of generator differentials on a free DG module

Description

See also

Ways to use this method: