subDGAlgebra -- The sub-DG algebra generated by a chosen subset of DG generators

Usage:

B = subDGAlgebra(A, keepIdx)
Inputs:
- A, an instance of the type DGAlgebra,
- keepIdx, a list, A list of integers giving the indices (into 0 .. numgens A.natural - 1) of the DG generators to keep. Duplicates and out-of-range indices raise an error.
Optional inputs:
- InitializeDegreeZeroHomology => a Boolean value, default value true, Whether to compute H_0 of the result eagerly. Default true.
- InitializeComplex => a Boolean value, default value false, Whether to build the underlying complex eagerly. Default false.
Outputs:
- B, an instance of the type DGAlgebra, A DG algebra over A.ring whose DG generators are the keepIdx-indexed generators of A in sorted order, with their differentials restricted accordingly.

Description

The subset keepIdx must be d-closed: if the differential of a kept generator uses a dropped generator, subDGAlgebra raises an error rather than silently returning a non-DG object. This protects downstream code from accidentally producing inconsistent structures.

i1 : R = QQ[x, y] / ideal(x^2, y^2)

o1 = R

o1 : QuotientRing

i2 : A = koszulComplexDGA R

o2 = {Ring => R                          }
      Underlying algebra => R[T   ..T   ]
                               1,1   1,2
      Differential => {x, y}

o2 : DGAlgebra

i3 : B = subDGAlgebra(A, {0})

o3 = {Ring => R                    }
      Underlying algebra => R[T   ]
                               1,1
      Differential => {x}

o3 : DGAlgebra

i4 : numgens B.natural

o4 = 1

Dropping a generator whose image is referenced in a kept generator's differential is caught:

i5 : R = QQ[x] / ideal(x^2)

o5 = R

o5 : QuotientRing

i6 : A = koszulComplexDGA R

o6 = {Ring => R                    }
      Underlying algebra => R[T   ]
                               1,1
      Differential => {x}

o6 : DGAlgebra

i7 : A' = adjoinVariables(A, {x * (gens A.natural)#0})

o7 = {Ring => R                          }
      Underlying algebra => R[T   , T   ]
                               1,1   2,1
      Differential => {x, x*T   }
                             1,1

o7 : DGAlgebra

i8 : try subDGAlgebra(A', {1}) else "error: kept differential uses dropped generator"

o8 = error: kept differential uses dropped generator

Caveat

Duplicate or out-of-range entries in keepIdx raise an error. keepIdx is internally sorted, so the generator order of the output depends only on which indices appear.

Ways to use subDGAlgebra:

subDGAlgebra(DGAlgebra,List)

For the programmer

The object subDGAlgebra is a method function with options.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/DGAlgebras/doc.m2:6585:0.

subDGAlgebra -- The sub-DG algebra generated by a chosen subset of DG generators

Description

Caveat

See also

Ways to use subDGAlgebra:

For the programmer