exterior algebras -- a polynomial ring with skew-commutative variables

An exterior algebra is a polynomial ring $R$ where multiplication of the variables obeys the commutation relation $xy = (-1)^{\textrm{deg}(x) \textrm{deg}(y)}yx$. One notable consequence of this is that if $\textrm{deg}(x)$ is odd, then $x^2 = 0$.

Here, $\textrm{deg}(x)$ is the degree of $x$ - or the first degree of $x$ in case $R$ is multi-graded. By default, the degree of each variable in a polynomial ring is 1, so in this case we have the simple rule $xy = -yx$ for multiplying variables.

Create an exterior algebra with explicit generators by creating a polynomial ring with the option SkewCommutative.

i1 : R = QQ[x,y,z, SkewCommutative => true]

o1 = R

o1 : PolynomialRing, 3 skew commutative variable(s)

i2 : y*x

o2 = -x*y

o2 : R

i3 : (x+y+z)^2

o3 = 0

o3 : R

i4 : basis R

o4 = | 1 x xy xyz xz y yz z |

             1      8
o4 : Matrix R  <-- R

i5 : basis(2,R)

o5 = | xy xz yz |

             1      3
o5 : Matrix R  <-- R

You can declare that only a subset of the variables are skew-commutative.

i6 : R = QQ[a..c, SkewCommutative => {b, c}]

o6 = R

o6 : PolynomialRing, 2 skew commutative variable(s)

i7 : a*b == b*a

o7 = true

i8 : a*c == c*a

o8 = true

i9 : b*c == -c*b

o9 = true

The degree of the variables can be specified just as in the commutative case.

i10 : R = QQ[a,b,r,s,t, SkewCommutative=>true, Degrees=>{2,2,1,1,1}]

o10 = R

o10 : PolynomialRing, 5 skew commutative variable(s)

i11 : r*a == a*r

o11 = false

i12 : a*a

o12 = 0

o12 : R

i13 : f = a*r+b*s; f^2

o14 = -2a*b*r*s

o14 : R

i15 : basis(2,R)

o15 = | a b rs rt st |

              1      5
o15 : Matrix R  <-- R

As usual in Macaulay2, matrices are actually matrices over $R^\textrm{op}$ and so matrix arithmetic over exterior algebras is slightly different from what you see in the commutative case.

i16 : R = QQ[a..d, SkewCommutative => true]

o16 = R

o16 : PolynomialRing, 4 skew commutative variable(s)

i17 : A = matrix {{a, b}, {1, 1}}

o17 = | a b |
      | 1 1 |

              2      2
o17 : Matrix R  <-- R

i18 : B = matrix {{c, 1}, {d, 1}}

o18 = | c 1 |
      | d 1 |

              2      2
o18 : Matrix R  <-- R

i19 : A * B

o19 = | -ac-bd a+b |
      | c+d    2   |

              2      2
o19 : Matrix R  <-- R

See right modules or left modules? for more details.

You may compute Gröbner bases, syzygies, and form quotient rings of these skew commutative rings. Warning that quotienting by an ideal which is not a 2-sided ideal will produce quotient ring where multiplication is not well defined on coset representatives.

i20 : R = QQ[a..d, SkewCommutative => true]

o20 = R

o20 : PolynomialRing, 4 skew commutative variable(s)

i21 : I = ideal {a*b + c}

o21 = ideal(a*b + c)

o21 : Ideal of R

i22 : promote(I_0 * d, R/I)

o22 = 2c*d

         R
o22 : -------
      a*b + c

i23 : promote(I_0, R/I) * promote(d, R/I)

o23 = 0

         R
o23 : -------
      a*b + c

exterior algebras -- a polynomial ring with skew-commutative variables

Menu