posetConnectedSum -- constructs the connected sum of several posets

Usage:

posetConnectedSum L

posetConnectedSum(f, g)
Inputs:
- L, a list, of rank-preserving injective PosetMaps.
- f, a map of posets,
- g, a map of posets,
Outputs:
- an instance of the type Poset,

Description

In this construction, several posets are glued together at the top and at the bottom. Suppose $A,B$ are self-dual posets, $C$ is a poset, and $i_A: C \rightarrow A$ and $i_B: C \rightarrow B$ are rank-preserving, injective poset maps. Let $d_A: A \rightarrow A^{\operatorname{op}}$ and $d_B: B \rightarrow B^{\operatorname{op}}$ be the dual isomorphisms. The connected sum of $A$ and $B$ with respect to $i_A, i_B$ is the poset obtained by taking the disjoint union of $A$ and $B$, identifying the image of $i_A$ with the image of $i_B$, and identifying the image of $d_A \circ i_A$ with the image of $d_B \circ i_B$. This construction can also be generalized to connected sums of more than two posets.

This is a generalization of posetClosedProduct.

Here is the connected sum of the chain $[5]$ with itself with respect to the inclusion map $[2]\hookrightarrow[5]$ with $1 \mapsto 1$ and $2 \mapsto 2$.

i1 : i = map(chain 5, chain 2, {1=>1, 2=>2})

o1 = PosetMap{1 => 1                                  }
              2 => 2
              source => Relation Matrix: | 1 1 |
                                         | 0 1 |
              target => Relation Matrix: | 1 1 1 1 1 |
                                         | 0 1 1 1 1 |
                                         | 0 0 1 1 1 |
                                         | 0 0 0 1 1 |
                                         | 0 0 0 0 1 |

o1 : PosetMap

i2 : A = posetConnectedSum(i, i)

o2 = A

o2 : Poset

i3 : areIsomorphic( A, adjoinMin adjoinMax product(chain 2, chain 2) )

o3 = true

Let $P = [2] \times [2]$, let $Q = [2] \times [5]$. There are two different connected sums over $P$ of $Q$ with itself. The map $f: P \rightarrow Q$ is the inclusion map with $(1,2) \mapsto (1,2)$ and $(2,1) \mapsto (2,1)$. The map $g: P \rightarrow Q$ is the other rank-preserving injection, with $(1,2) \mapsto (2,1)$ and $(2,1) \mapsto (1,2)$.

i4 : P = product(chain 2, chain 2)

o4 = P

o4 : Poset

i5 : Q = product(chain 2, chain 5)

o5 = Q

o5 : Poset

i6 : f = map(Q, P, {{1,1}, {1,2}, {2,1}, {2,2}})

o6 = PosetMap{{1, 1} => {1, 1}}
              {1, 2} => {1, 2}
              {2, 1} => {2, 1}
              {2, 2} => {2, 2}
              source => P
              target => Q

o6 : PosetMap

i7 : g = map(Q, P, {{1,1}, {2,1}, {1,2}, {2,2}})

o7 = PosetMap{{1, 1} => {1, 1}}
              {1, 2} => {2, 1}
              {2, 1} => {1, 2}
              {2, 2} => {2, 2}
              source => P
              target => Q

o7 : PosetMap

i8 : R = posetConnectedSum(f, g)

o8 = R

o8 : Poset

i9 : S = posetConnectedSum(f, f)

o9 = S

o9 : Poset

i10 : areIsomorphic(R, S)

o10 = false

i11 : areIsomorphic(S, product(chain 2, A))

o11 = true

Ways to use posetConnectedSum:

posetConnectedSum(List)
posetConnectedSum(PosetMap,PosetMap)

For the programmer

The object posetConnectedSum is a method function.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/MacaulayPosets.m2:1624:0.