posetFiberProduct -- constructs the fiber product of several posets

Usage:

posetFiberProduct L

posetFiberProduct(f, g)
Inputs:
- L, a list, a list of rank-preserving injective PosetMaps.
- f, a map of posets,
- g, a map of posets,
Outputs:
- an instance of the type Poset,

Description

In this construction, several posets are glued together along a common subposet. Suppose $(A, \leq_A), (B, \leq_B), (C, \leq_C)$ are posets and $\iota_A: C \rightarrow A$ and $\iota_B: C \rightarrow B$ are rank-preserving, injective, and monotone. Then, we have a fiber product \[A \times_C B = (A \setminus \iota_A(C)) \sqcup (B \setminus \iota_B(C)) \sqcup C\] with $a \geq c$ iff $a \geq_A \iota_A(c)$ for $a \in A$ and $c \in C$, and $b \geq c$ iff $b \geq_B \iota_A(c)$ for $b \in A$ and $c \in C$.

This is a generalization of posetWedgeProduct.

i1 : P = product(chain 2, chain 2)

o1 = P

o1 : Poset

i2 : Q = product(chain 2, chain 3)

o2 = Q

o2 : Poset

i3 : f = map(Q, P, {{1,1}, {1,2}, {2,1}, {2,2}})

o3 = PosetMap{{1, 1} => {1, 1}}
              {1, 2} => {1, 2}
              {2, 1} => {2, 1}
              {2, 2} => {2, 2}
              source => P
              target => Q

o3 : PosetMap

i4 : g = map(Q, P, {{1,1}, {2,1}, {1,2}, {2,2}})

o4 = PosetMap{{1, 1} => {1, 1}}
              {1, 2} => {2, 1}
              {2, 1} => {1, 2}
              {2, 2} => {2, 2}
              source => P
              target => Q

o4 : PosetMap

i5 : R = (ZZ/2)[x,y]

o5 = R

o5 : PolynomialRing

i6 : I = monomialIdeal(x^3, x^2 * y^2, y^3)

                     3   2 2   3
o6 = monomialIdeal (x , x y , y )

o6 : MonomialIdeal of R

i7 : areIsomorphic(posetFiberProduct(f, g), getPoset(R/I))

o7 = true

i8 : chainWedgePoset = product(chain 2, adjoinMin posetWedgeProduct(chain 2, chain 2))

o8 = chainWedgePoset

o8 : Poset

i9 : areIsomorphic(posetFiberProduct(f, f), chainWedgePoset)

o9 = true

Ways to use posetFiberProduct:

posetFiberProduct(List)
posetFiberProduct(PosetMap,PosetMap)

For the programmer

The object posetFiberProduct is a method function.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/MacaulayPosets.m2:1624:0.

posetFiberProduct -- constructs the fiber product of several posets

Description

See also

Ways to use posetFiberProduct:

For the programmer