matchingField -- Construct a matching field

Usage:

L = matchingField(tupleSizeList, tupleIndices, weightMatrix)

L = matchingField(tupleSizeList, n, tupleList)
Inputs:
- n, an integer, positive integer; the tuples have entries in 1 .. n
- tupleSizeList, a list, positive integers; the sizes of the tuples of the matching field
- tupleIndices, a list, list of subsets; the indices of columns of matrix that form tuples (subsets of 0 .. n-1)
- tupleList, a list, list of subsets; the tuples of the matching fields (subsets of 1 .. n)
- weightMatrix, a matrix, induces the matching field
Outputs:
- L, an instance of the type MatchingField,

Description

This function is the basic constructor for a matching field. The function outputs an instance of type MatchingField, which represents the matching field and stores all data related and computed about it.

It is recommended for users to use the functions grMatchingField to construct matching fields for the Grassmannian and flMatchingField to construct matching fields for partial flag varieties. These functions produce objects of type GrMatchingField and FlMatchingField respectively, which have clear uses in this package.

There are two basic ways to define a matching field. The first way is to supply a weight matrix that induces the matching field. This produces a coherent matching field and is well-defined if the weight matrix is generic.

i1 : M = matrix {{0,0,0,0}, {1,3,2,4}}

o1 = | 0 0 0 0 |
     | 1 3 2 4 |

              2       4
o1 : Matrix ZZ  <-- ZZ

i2 : L1 = matchingField({1, 2}, {{0}, {1}, {0, 1}, {0, 2}, {0, 3}}, M)

o2 = Matching Field: tuple sizes 1, 2; with values 1 .. 4

o2 : MatchingField

i3 : getTuples L1

o3 = {{1}, {2}, {2, 1}, {3, 1}, {4, 1}}

o3 : List

In the above example, we construct a matching field induced by the given weight matrix. The tuples for the matching field are listed in RevLex order with subsets in increasing size.

The second way to define a matching field is to list out its tuples.

i4 : T = {{1,4}, {2,4}, {3,4}, {3,1}, {3,2}, {1,2}}

o4 = {{1, 4}, {2, 4}, {3, 4}, {3, 1}, {3, 2}, {1, 2}}

o4 : List

i5 : L2 = matchingField({2}, 4, T)

o5 = Matching Field: tuple sizes 2; with values 1 .. 4

o5 : MatchingField

i6 : getTuples L2

o6 = {{1, 2}, {3, 1}, {3, 2}, {1, 4}, {2, 4}, {3, 4}}

o6 : List

As shown in the example above, the first argument "{2}" specifies the sizes of the tuples of the matching field. The second argument "4" specifies the maximum value of elements in the tuples. The third argument is the list of tuples of the matching field. Note that the tuples can be supplied in any order.

It is recommended to use Grassmannian matching fields or partial flag matching fields for computing toric degenerations as these objects have access to the functions isToricDegeneration and plueckerIdeal.

Ways to use matchingField:

matchingField(List,List,Matrix)
matchingField(List,ZZ,List)

For the programmer

The object matchingField is a method function.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/MatchingFields.m2:2793:0.

matchingField -- Construct a matching field

Description

See also

Menu

Ways to use matchingField:

For the programmer