Macaulay2 » Documentation
Packages » SchurFunctors :: schur
next | previous | forward | backward | up | index | toc

schur -- the Schur functor applied to a matrix

Description

For each partition $\lambda$, $S_\lambda$ is a polynomial functor. Applied to a morphism $f : E \to F$ of free modules it yields a morphism $S_\lambda(f) : S_\lambda(E) \to S_\lambda(F)$, and the construction is functorial: $S_\lambda(f \circ g) = S_\lambda(f) \circ S_\lambda(g)$ and $S_\lambda(\mathrm{id}_E) = \mathrm{id}_{S_\lambda(E)}$.

The source and target matrices have modules that carry the same cached data as returned by schurModule.

i1 : R = QQ[x_1,x_2,x_3];
 
i2 : F = map(R^1, R^3, vars R);

             1      3
o2 : Matrix R  <-- R
 
i3 : schur({2}, F)                          -- 2nd Veronese embedding

o3 = | x_1^2 x_1x_2 x_1x_3 x_2^2 x_2x_3 x_3^2 |

             1      6
o3 : Matrix R  <-- R

Classical specializations. Top exterior power = determinant:

i4 : F = matrix{{1_QQ,2,4},{3,9,27},{4,16,64}};

              3       3
o4 : Matrix QQ  <-- QQ
 
i5 : det F

o5 = 24

o5 : QQ
 
i6 : schur({1,1,1}, F)

o6 = | 24 |

              1       1
o6 : Matrix QQ  <-- QQ

Second exterior power = matrix of $2\times2$ minors:

i7 : entries schur({1,1}, F)

o7 = {{3, 15, 18}, {8, 48, 64}, {12, 84, 144}}

o7 : List
 
i8 : entries gens minors(2, F)

o8 = {{3, 8, 12, 15, 48, 84, 18, 64, 144}}

o8 : List
 
i9 : S = schur({3,1}, id_(QQ^3));               -- identity maps to the identity

              15       15
o9 : Matrix QQ   <-- QQ
 
i10 : S == id_(source S)

o10 = true

Composition is compatible with matrix composition:

i11 : A = random(QQ^3, QQ^3);

               3       3
o11 : Matrix QQ  <-- QQ
 
i12 : B = random(QQ^3, QQ^3);

               3       3
o12 : Matrix QQ  <-- QQ
 
i13 : schur({2,1}, A * B) == schur({2,1}, A) * schur({2,1}, B)

o13 = true

Caveat

The partition lambda should be nonempty and weakly decreasing.

See also

Ways to use schur:

  • schur(List,Matrix)

For the programmer

The object schur is a method function.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/SchurFunctors.m2:2008:0.