weylStraighten -- straighten a Weyl filling into a linear combination of Weyl-semistandard tableaux

• Usage:

  weylStraighten T

  weylStraighten H

  weylStraighten(T, W)

  weylStraighten(H, W)

• Inputs:
  • T, an instance of the type WeylFilling,
  • H, a hash table, a formal $\mathbb{Z}$-linear combination of WeylFillings (all of the same shape)
  • W, a module, (optional) a Weyl module produced by weylModule
• Outputs:
  • a HashTable keyed by Weyl-semistandard fillings, or (when a module is supplied) the corresponding Vector in W

i1 : U = weyl {{1,2},{0,0}}

     +-+-+
o1 = |1|2|
     |0|0|
     +-+-+

o1 : WeylFilling

i2 : weylStraighten U

               +-+-+
o2 = HashTable{|0|0| => 1}
               |1|2|
               +-+-+

o2 : HashTable

i3 : H = hashTable {
          (weyl {{1,2},{0,0}}, 1),
          (weyl {{0,2},{1,0}}, -1)};

i4 : weylStraighten H

               +-+-+
o4 = HashTable{|0|0| => 2}
               |1|2|
               +-+-+

o4 : HashTable

i5 : W = weylModule({2,2}, QQ^3);

i6 : v = weylStraighten(weyl {{0,2},{1,0}}, W)

o6 = |  0 |
     | -1 |
     |  0 |
     |  0 |
     |  0 |
     |  0 |

       6
o6 : QQ

i7 : printWeylModuleElement(v, W)
   +-+-+
-1*|0|0| 
   |1|2|
   +-+-+