toSn -- Promote a Schur-basis element into an Sn character ring

Usage:

g = toSn(f, T)
Inputs:
- f, a ring element, element of a SchurRing or symmetricRing
- T, a Schur ring, target ring; must have GroupActing => "Sn"
Outputs:
- g, a ring element, the element of T with the same partition-indexed coefficients as f (after converting f to the Schur basis)

Description

The GL and Sn flavors of a SchurRing share the same partition index set -- the distinction is in the multiplication (LR product vs.\ internal product) and in the semantics (polynomial GL character vs.\ Frobenius characteristic of an $S_n$-class function). toSn simply carries the coefficient data across.

Finite-rank targets drop partitions with more than numgens T parts. Inputs in a variant basis ("Sp", "O", "RatGL", "Monomial") are first expanded in the plain Schur basis via toS.

i1 : S  = schurRing(QQ, s,  4);

i2 : Sn = schurRing(QQ, n, 4, GroupActing => "Sn");

i3 : toSn(s_{2,1} + 3 * s_{1,1,1}, Sn)

o3 = n    + 3n
      2,1     1,1,1

o3 : Sn

i4 : a = toSn(s_3, Sn);

i5 : a * a

o5 = n
      3

o5 : Sn

Partition labels on the two sides match, but the multiplication does not: the GL (LR) product of $s_{2,1}$ with itself lives in degree 6, while the $S_3$-Kronecker product of the standard representation with itself stays in degree 3 and decomposes as $n_{3} + n_{2,1} + n_{1,1,1}$:

i6 : S3  = schurRing(QQ, s3, 3);

i7 : Sn3 = schurRing(QQ, n3, 3, GroupActing => "Sn");

i8 : s3_{2,1} * s3_{2,1}

o8 = s3    + s3      + s3    + 2s3      + s3
       4,2     4,1,1     3,3      3,2,1     2,2,2

o8 : S3

i9 : b = toSn(s3_{2,1}, Sn3);

i10 : b * b

o10 = n3  + n3    + n3
        3     2,1     1,1,1

o10 : Sn3

Inputs in variant bases ("Sp", "O", "RatGL", "Monomial") are first expanded through toS, so toSn also accepts symplectic or orthogonal characters and returns the corresponding $S_n$-class function:

i11 : Sp  = schurRing(QQ, sp,  3, GroupActing => "Sp");

i12 : toSn(sp_{2,1}, Sn3)

o12 = n3    - n3
        2,1     1

o12 : Sn3

i13 : Oo  = schurRing(QQ, ooX, 3, GroupActing => "O");

i14 : toSn(ooX_{2,1}, Sn3)

o14 = n3    - n3
        2,1     1

o14 : Sn3

Ways to use toSn:

toSn(RingElement,SchurRing)

For the programmer

The object toSn is a method function.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/SchurRings.m2:8891:0.

toSn -- Promote a Schur-basis element into an Sn character ring

Description

See also

Ways to use toSn:

For the programmer