Macaulay2 » Documentation
Packages » SimplicialModules :: SimplicialModule _ ZZ
next | previous | forward | backward | up | index | toc

SimplicialModule _ ZZ -- access individual objects of a simplicial module

Description

The data of the modules of a simplicial module is stored in two different ways, depending on whether the simplicial module $S$ is obtained as the Dold-Kan image of some complex. If the simplicial module is obtained as a Dold-Kan image of some complex $C$, then for each $i$ there is a decomposition $$S_i = C_0 \oplus C_1^{\binom{i}{1}} \oplus \cdots \oplus C_j^{\binom{i}{j}} \oplus \cdots.$$ Thus the individual terms $C_j^{\binom{i}{j}}$ may be accessed as the $(i,j)$-component of the simplicial module. If $S$ is not obtained as a Dold-Kan image, then each term is considered singly indexed with no additional components.

i1 : S = ZZ/101[a..c]

o1 = S

o1 : PolynomialRing
 
i2 : C = simplicialModule(freeResolution coker vars S, 4, Degeneracy => true)

      1      4      10      20      35
o2 = S  <-- S  <-- S   <-- S   <-- S  <-- ...
                                    
     0      1      2       3       4

o2 : SimplicialModule
 
i3 : C.?complex

o3 = true
 
i4 : C.complex

      1      3      3      1
o4 = S  <-- S  <-- S  <-- S
                           
     0      1      2      3

o4 : Complex
 
i5 : C_(1,0) == C.complex_0

o5 = true
 
i6 : C_(1,1) == C.complex_1

o6 = true
 
i7 : C_(2,1) == C.complex_1 ++ C.complex_1

o7 = true
 
i8 : tC = C ** C

      1      16      100      400      1225
o8 = S  <-- S   <-- S    <-- S    <-- S    <-- ...
                                       
     0      1       2        3        4

o8 : SimplicialModule
 
i9 : tC.?complex

o9 = false
 
i10 : tC_2

       100
o10 = S

o10 : S-module, free, degrees {0..1, 5:1, 3:2, 1..2, 5:2, 3:3, 1..2, 5:2, 3:3, 1..2, 5:2, 3:3, 1..2, 5:2, 3:3, 1..2, 5:2, 3:3, 1..2, 5:2, 3:3, 2..3, 5:3, 3:4, 2..3, 5:3, 3:4, 2..3, 5:3, 3:4}

If the simplicial object is obtained as a Dold-Kan image, then using an integer subscript will automatically take the direct sum over all the terms of the complex appearing in that degree (and cache the components of that direct sum accordingly).

i11 : C_3

       20
o11 = S

o11 : S-module, free, degrees {0..1, 8:1, 9:2, 3}
 
i12 : components C_3

        1   3   3   3   3   3   3   1
o12 = {S , S , S , S , S , S , S , S }

o12 : List
 
i13 : (C_3)_[1,2,3] --extract the inclusion of (C.complex_1)^3

o13 = {0} | 0 0 0 0 0 0 0 0 0 |
      {1} | 1 0 0 0 0 0 0 0 0 |
      {1} | 0 1 0 0 0 0 0 0 0 |
      {1} | 0 0 1 0 0 0 0 0 0 |
      {1} | 0 0 0 1 0 0 0 0 0 |
      {1} | 0 0 0 0 1 0 0 0 0 |
      {1} | 0 0 0 0 0 1 0 0 0 |
      {1} | 0 0 0 0 0 0 1 0 0 |
      {1} | 0 0 0 0 0 0 0 1 0 |
      {1} | 0 0 0 0 0 0 0 0 1 |
      {2} | 0 0 0 0 0 0 0 0 0 |
      {2} | 0 0 0 0 0 0 0 0 0 |
      {2} | 0 0 0 0 0 0 0 0 0 |
      {2} | 0 0 0 0 0 0 0 0 0 |
      {2} | 0 0 0 0 0 0 0 0 0 |
      {2} | 0 0 0 0 0 0 0 0 0 |
      {2} | 0 0 0 0 0 0 0 0 0 |
      {2} | 0 0 0 0 0 0 0 0 0 |
      {2} | 0 0 0 0 0 0 0 0 0 |
      {3} | 0 0 0 0 0 0 0 0 0 |

              20      9
o13 : Matrix S   <-- S

Indices that are outside of the top degree automatically return the zero object.

i14 : C_(-1,3)

o14 = 0

o14 : S-module
 
i15 : C_-7

o15 = 0

o15 : S-module

See also

Ways to use this method:

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/SimplicialModules/SimplicialModuleDOC.m2:681:0.