DoublySpecialCubicFourfold -- the class of all cubic fourfolds belonging to the intersection of two Hassett divisors

Description

A cubic fourfold $X\subset \mathbb{P}^5$ is called doubly special if it belongs to the intersection of two Hassett divisors $\mathcal{C}_{d_1} \cap \mathcal{C}_{d_2}$. This means that the algebraic part of its middle cohomology, $H^{2,2}(X, \mathbb{Z})$, has rank at least 3, containing the classes of two surfaces $S$ and $T$ which, together with the square of the hyperplane class $h^2$, span a saturated lattice of rank 3.

An object of the class DoublySpecialCubicFourfold can be thought of as a triple $(S,T,X)$, where $X$ is a cubic fourfold and $S, T$ are two surfaces contained in $X$. Internally, it is represented as a nested structure, where the cubic fourfold containing $S$ is built upon the cubic fourfold containing $T$. This nesting allows the object to inherit the functions and properties of the cubic fourfold containing $S$.

Such an object is constructed using the operator & to combine the two surfaces. Specifically, if $S$ and $T$ are two surfaces and $X$ is a cubic fourfold containing both, an object is created via the function specialFourfold (or equivalently cubicFourfold) as follows:

i1 : K = ZZ/33331;

i2 : S = PP_K^(2,2); -- the Veronese surface

o2 : ProjectiveVariety, surface in PP^5

i3 : T = random({{2},{1},{1}}, sum(3, i -> point S)); -- a 3-secant quadric to S

o3 : ProjectiveVariety, surface in PP^5

i4 : X = random(3, S + T);

o4 : ProjectiveVariety, hypersurface in PP^5

i5 : X = specialFourfold(S & T, X)

o5 = X

o5 : ProjectiveVariety, cubic fourfold containing two surfaces of degrees 4 and 2, sectional genera 0 and 0

i6 : surface X

o6 = S

o6 : ProjectiveVariety, surface in PP^5

i7 : discriminant X

o7 = 20

If the second argument (the cubic fourfold) is omitted, the constructor will automatically provide a random cubic fourfold containing the union $S \cup T$. A summary of the created fourfold $X$ is provided by the function describe, while the pair of surfaces $(S,T)$ defining the doubly special structure can be retrieved with the function surfaces.

i8 : X = specialFourfold(S & T);

o8 : ProjectiveVariety, cubic fourfold containing two surfaces of degrees 4 and 2, sectional genera 0 and 0

i9 : describe X

o9 = Cubic fourfold in C_20 ∩ C_8 over K of lattice discriminant
         | 3 4  2 |
     det(| 4 12 3 |) = 53
         | 2 3  4 |
     containing two surfaces:
      - smooth rational surface of degree 4 and sectional genus 0
        cut out by 6 hypersurfaces of degree 2
      - surface of degree 2 and sectional genus 0
        cut out by 3 hypersurfaces of degrees 1^2 2^1 
     Intersection of the surfaces: 3 points

i10 : surfaces X

o10 = (S, T)

o10 : Sequence

See also

• CubicFourfold -- the class of all special cubic fourfolds
• polarizedK3surface(DoublySpecialCubicFourfold) -- polarized K3 surface associated to a doubly special cubic fourfold
• surfaces -- get the special surfaces contained in the cubic fourfold