createEquations -- Finds explicit equations satisfied by the parameters of a Frobenius lift up to a given degree

Usage:

J = createEquations(d, I)

J = createEquations(d, f)

J = createEquations(d, R)
Inputs:
- d, an integer,
- I, an ideal,
- f, a ring element,
- R, a quotient ring,
Optional inputs:
- Homogeneous => ..., default value false
- PerturbationTerm => ..., default value null
Outputs:
- J, an ideal,

Description

If R = S/I and one represents the choice of a Frobenius lift on W_2(k)(S) by polynomials of degree at most d, this method returns the equations that the coefficients of those polynomials have to satisfy for the resulting Frobenius lift to descend to W_2(k)(S/I). The output is an ideal J in variables c_{{a_1..a_n},j}, where c_{{a_1..a_n},j} is the coefficient of x_1^{a_1}..x_n^{a_n} in the polynomial that gives the image of x_j under the Frobenius lift; the exponents a_i satisfy sum a_i \leq d.

i1 : S = (ZZ/2)[x,y]

o1 = S

o1 : PolynomialRing

i2 : I = ideal(x*y)

o2 = ideal(x*y)

o2 : Ideal of S

i3 : J = createEquations(2, I)

o3 = ideal (c          , c          , c          , c          , c          ,
             {2, 0},{2}   {1, 0},{2}   {0, 2},{1}   {0, 1},{1}   {0, 0},{2} 
     ------------------------------------------------------------------------
     c          )
      {0, 0},{1}

              ZZ
o3 : Ideal of --[c          , c          , c          , c          , c          , c          , c          , c          , c          , c          , c          , c          ]
               2  {0, 0},{1}   {0, 0},{2}   {0, 1},{1}   {0, 1},{2}   {0, 2},{1}   {0, 2},{2}   {1, 0},{1}   {1, 0},{2}   {1, 1},{1}   {1, 1},{2}   {2, 0},{1}   {2, 0},{2}

If one wants only to find the equations for homogeneous polynomials, one can use the Homogeneous option. One can specify a different lifting of I to W_2(k)[x_1..x_n] by using the PerturbationTerm option to specify the coefficients of p in the lift of the defining equations.

i4 : S = (ZZ/2)[x,y]

o4 = S

o4 : PolynomialRing

i5 : I = ideal(x*y)

o5 = ideal(x*y)

o5 : Ideal of S

i6 : J = createEquations(2, I,Homogeneous=>true,PerturbationTerm=>{0})

o6 = ideal (c          , c          )
             {2, 0},{2}   {0, 2},{1}

              ZZ
o6 : Ideal of --[c          , c          , c          , c          , c          , c          ]
               2  {0, 2},{1}   {0, 2},{2}   {1, 1},{1}   {1, 1},{2}   {2, 0},{1}   {2, 0},{2}

i7 : J = createEquations(2, I,Homogeneous=>true,PerturbationTerm=>{1}) -- no solutions!

o7 = ideal 1

              ZZ
o7 : Ideal of --[c          , c          , c          , c          , c          , c          ]
               2  {0, 2},{1}   {0, 2},{2}   {1, 1},{1}   {1, 1},{2}   {2, 0},{1}   {2, 0},{2}

Ways to use createEquations:

createEquations(ZZ,Ideal) (missing documentation)
createEquations(ZZ,Ring) (missing documentation)
createEquations(ZZ,RingElement) (missing documentation)

For the programmer

The object createEquations is a method function with options.

The source of this document is in /build/reproducible-path/macaulay2-1.26.05+ds/M2/Macaulay2/packages/WittVectors/Documentation.m2:1100:0.