Qt Creator Manual

Creating a Qt Quick 1 Application

Note: Qt Quick Designer only supports Qt Quick 1, which is offered in Qt 5 only for compatibility with Qt 4. We recommend that you use Qt Quick 2 for new Qt 5 applications. You can use the code editor in the Design mode to develop Qt Quick 2 applications. For more information, see the Qt 5 documentation.

This tutorial uses built-in QML elements and illustrates basic concepts of Qt Quick 1.

This tutorial describes how to use the Qt Creator to implement the states and transitions example application. The example application displays a Qt logo that moves between three rectangles on the page when you click them.

"States and transitions example"

For more information about using Qt Quick Designer, see Developing Qt Quick Applications.

Creating the Project

  1. Select File > New File or Project > Applications > Qt Quick 1 Application (Built-in Elements) > Choose.
  2. In the Name field, type Transitions.
  3. In the Create in field, enter the path for the project files. For example, C:\Qt\examples, and then click Next (on Windows and Linux) or Continue (on Mac OS).
  4. Select kits for running and building your project, and then click Next.

    Note: Kits are listed if they have been specified in Tools > Options > Build & Run > Kits.

  5. Select Next in the following dialogs to use the default settings.
  6. Review the project settings, and click Finish (on Windows and Linux) or Done (on Mac OS) to create the project.
  7. Press Ctrl+R (or Cmd+R)to run the application.

Qt Creator generates a default QML file that you can modify to create the main view of the application.

"Transitions project in Edit mode"

Creating the Main View

The main view of the application displays a Qt logo in the top left corner of the screen and two empty rectangles.

To use the states.png image in your application, you must copy it to the project directory (same subdirectory as the QML file) from the examples directory in the Qt installation directory. For example: C:\QtSDK\Examples\4.7\declarative\animation\states. The image appears in the Resources pane. You can also use any other image or a QML element, instead.

  1. In the Projects view, double-click the main.qml file to open it in the code editor.
  2. Click Design to open the file in Qt Quick Designer.

    "Transitions project in Design Mode"

  3. In the Navigator pane, select Text and press Delete to delete it.
  4. Select Rectangle to edit its properties.

    "Page properties"

    1. In the Id field, enter page, to be able to reference the rectangle from other places.
    2. In the Colors group, Rectangle field, set the color to #343434.
  5. In the Library view, Resources tab, select states.png and drag and drop it to the canvas.

    "Image properties"

    1. In the Id field, enter icon.
    2. In the Position field, set X to 10 and Y to 20.
  6. In the Library view, Items tab, select Rectangle, drag and drop it to the canvas, and edit its properties.

    "Rectangle properties"

    1. In the Id field, enter topLeftRect.
    2. In the Size field, set W and H to 64, for the rectangle size to match the image size.
    3. In the Colors group, Rectangle field, click the (Transparent) button to make the rectangle transparent.
    4. In the Border field, set the border color to #808080.
    5. In the Rectangle group, Border field, set the border width to 1.

      Note: If the Border field does not appear after you set the border color, try setting the border color to solid by clicking the (Solid Color) button.

    6. In the Radius field, select 6 to create rounded corners for the rectangle.
    7. Click Layout, and then click the top and left anchor buttons to anchor the rectangle to the top left corner of the page.

      "Layout tab"

    8. In the Margin field, select 20 for the top anchor and 10 for the left anchor.
  7. In the Navigator pane, drag and drop the Mouse Area element from page to topLeftRect to make it apply only to the rectangle and not to the whole page.
  8. Edit Mouse Area properties:
    1. Click Layout, and then click the (Fill to Parent) button to anchor the mouse area to the rectangle.
    2. In the code editor, edit the pointer to the clicked expression in the mouse area element, as illustrated by the following code snippet:
       MouseArea {
           anchors.fill: parent
           onClicked: page.state = ''
       }

      The expression sets the state to the base state and returns the image to its initial position.

    The qml.main file should now look as follows:

     import QtQuick 1.1
    
     Rectangle {
         id: page
         width: 360
         height: 360
         color: "#343434"
    
         Image {
             id: icon
             x: 10
             y: 20
             source: "states.png"
         }
    
         Rectangle {
             id: topLeftRect
             y: 20
             width: 64
             height: 64
             color: "#00000000"
             radius: 6
             anchors.left: parent.left
             anchors.leftMargin: 10
             anchors.top: parent.top
             anchors.topMargin: 20
             border.color: "#808080"
    
             MouseArea {
                 id: mousearea1
                 anchors.fill: parent
                 onClicked: page.state = ' '
                 }
             }
  9. In the Navigator pane, copy topLeftRect (by pressing Ctrl+C) and paste it to the canvas twice (by pressing Ctrl+V). Qt Creator renames the new instances of the element topLeftRect1 and topLeftRect2.
  10. Select topLeftRect1 and edit its properties:
    1. In the Id field, enter middleRightRect.
    2. In Layout, select the vertical center anchor button and then the right anchor button to anchor the rectangle to the middle right margin of the screen.
    3. In the Margin field, select 10 for the right anchor and 0 for the vertical center anchor.
    4. In the code editor,add a pointer to a clicked expression to the mouse area element. The following expression sets the state to State1:

      onClicked: page.state = 'State1'

      You will create State1 later.

  11. Select topLeftRect2 and edit its properties:
    1. In the Id field, enter bottomLeftRect.
    2. In Layout, select the bottom and left anchor buttons to anchor the rectangle to the bottom left margin of the screen.
    3. In the Margin field, select 20 for the bottom anchor and 10 for the left anchor.
    4. In the code editor, add a pointer to a clicked expression to the mouse area element. The following expression sets the state to State2:

      onClicked: page.state = 'State2'

      You will create State2 later.

      The qml.main file should now look as follows:

       import QtQuick 1.1
      
       Rectangle {
           id: page
           width: 360
           height: 360
           color: "#343434"
      
           Image {
               id: icon
               x: 10
               y: 20
               source: "states.png"
           }
      
           Rectangle {
               id: topLeftRect
               y: 20
               width: 64
               height: 64
               color: "#00000000"
               radius: 6
               anchors.left: parent.left
               anchors.leftMargin: 10
               anchors.top: parent.top
               anchors.topMargin: 20
               border.color: "#808080"
      
               MouseArea {
                   id: mousearea1
                   anchors.fill: parent
                   onClicked: page.state = ' '
                   }
               }
      
               Rectangle {
                   id: middleRightRect
                   x: 13
                   y: 16
                   width: 64
                   height: 64
                   color: "#00000000"
                   radius: 6
                   anchors.right: parent.right
                   anchors.rightMargin: 10
                   anchors.verticalCenter: parent.verticalCenter
                   border.color: "#808080"
                   MouseArea {
                       id: mousearea2
                       anchors.fill: parent
                       onClicked: page.state = 'State1'
                   }
               }
      
               Rectangle {
                   id: bottomLeftRect
                   y: 11
                   width: 64
                   height: 64
                   color: "#00000000"
                   radius: 6
                   anchors.left: parent.left
                   anchors.leftMargin: 10
                   anchors.bottom: parent.bottom
                   anchors.bottomMargin: 20
                   border.color: "#808080"
                   MouseArea {
                       id: mousearea3
                       anchors.fill: parent
                       onClicked: page.state = 'State2'
                   }
               }
  12. Press Ctrl+S to save the changes.
  13. Press Ctrl+R to run the application.

"States and transitions example"

You should see the Qt logo in the top left rectangle, and two additional rectangles in the center right and bottom left of the screen.

You can now create additional states to add views to the application.

Adding Views

In the .qml file, you already created pointers to two additional states: State1 and State2. To create the states:

  1. Click the empty slot in the States pane to create State1.
  2. Click the empty slot in the States pane to create State2.
  3. In the code editor, bind the position of the Qt logo to the rectangle to make sure that the logo is displayed within the rectangle when the view is scaled on different sizes of screens. Set expressions for the x and y properties, as illustrated by the following code snippet:
    
    

    "States"

    Note: When you set the expressions, drag and drop is disabled for the icon in Qt Quick Designer.

  4. Press Ctrl+R to run the application.

Click the rectangles to move the Qt logo from one rectangle to another.

Adding Animation to the View

Add transitions to define how the properties change when the Qt logo moves between states. The transitions apply animations to the Qt logo. For example, the Qt logo bounces back when it moves to the middleRightRect and eases into bottomLeftRect. Add the transitions in the code editor.

  1. In the code editor, add the following code to specify that when moving to State1, the x and y coordinates of the Qt logo change linearly over a duration of 1 second:
    
    
  2. You can use the Qt Quick toolbar for animation to change the easing curve type from linear to OutBounce:
    1. Click NumberAnimation in the code editor to display the icon, and then click the icon to open the toolbar:

      "Qt Quick toolbar for animation"

    2. In the Easing field, select Bounce.
    3. In the Subtype field, select Out.
  3. Add the following code to specify that when moving to State2, the x and y coordinates of the Qt logo change over a duration of 2 seconds, and an InOutQuad easing function is used:
    
    
  4. Add the following code to specify that for any other state changes, the x and y coordinates of the Qt logo change linearly over a duration of 200 milliseconds:
    
    
  5. Press Ctrl+R to run the application.

Click the rectangles to view the animated transitions.

Example Code

When you have completed the steps, the main.qml file should look as follows:


 import QtQuick 1.1

 Rectangle {
     id: page
     width: 360
     height: 360
     color: "#343434"

     Image {
         id: icon
         x: 10
         y: 20
         source: "states.png"
     }

     Rectangle {
         id: topLeftRect
         y: 20
         width: 64
         height: 64
         color: "#00000000"
         radius: 6
         anchors.left: parent.left
         anchors.leftMargin: 10
         anchors.top: parent.top
         anchors.topMargin: 20
         border.color: "#808080"

         MouseArea {
             id: mousearea1
             anchors.fill: parent
             onClicked: page.state = ' '
             }
         }

         Rectangle {
             id: middleRightRect
             x: 13
             y: 16
             width: 64
             height: 64
             color: "#00000000"
             radius: 6
             anchors.right: parent.right
             anchors.rightMargin: 10
             anchors.verticalCenter: parent.verticalCenter
             border.color: "#808080"
             MouseArea {
                 id: mousearea2
                 anchors.fill: parent
                 onClicked: page.state = 'State1'
             }
         }

         Rectangle {
             id: bottomLeftRect
             y: 11
             width: 64
             height: 64
             color: "#00000000"
             radius: 6
             anchors.left: parent.left
             anchors.leftMargin: 10
             anchors.bottom: parent.bottom
             anchors.bottomMargin: 20
             border.color: "#808080"
             MouseArea {
                 id: mousearea3
                 anchors.fill: parent
                 onClicked: page.state = 'State2'
             }
         }


         states: [
              State {
                  name: "State1"

                  PropertyChanges {
                      target: icon
                      x: middleRightRect.x
                      y: middleRightRect.y
                  }
              },
              State {
                  name: "State2"

                  PropertyChanges {
                      target: icon
                      x: bottomLeftRect.x
                      y: bottomLeftRect.y
                  }
              }
          ]

         transitions: [
         Transition {
                 from: "*"; to: "State1"
                 NumberAnimation {
                     properties: "x,y";
                     duration: 1000
                 }
             },
         Transition {
                 from: "*"; to: "State2"
                 NumberAnimation {
                     properties: "x,y";
                     easing.type: Easing.InOutQuad;
                     duration: 2000
                 }
             },
         Transition {
                  NumberAnimation {
                      properties: "x,y";
                      duration: 200
                  }
              }
         ]
 }